Friday, October 2, 2015

Mengatasi error 0x80070005 di Windows Update

Mengatasi error 0x80070005 di Windows Update - Kesalahan kode 0x80070005 juga dikenal sebagai "ACCESS DENIED." Ini biasanya terjadi ketika Anda tidak memiliki file atau registry yang diperlukan untuk menginstal izin pembaruan. (Karena file atau registry izin dapat diubah oleh malware, kami sarankan Anda memindai malware setelah Anda memperbaiki izin pembaruan windows.)

http://www.bapaknaga.com/2015/10/mengatasi-error-0x80070005-di-windows.html
error 0x80070005 di Windows Update

Untuk mengatasi error 0x80070005 tersebut, pastikan bahwa Anda logon sebagai administrator, dan kemudian install update lagi.

Jika masalah berlanjut, gunakan SubInACL tools untuk memperbaiki izin file dan registry. Untuk melakukannya, ikuti langkah berikut :

Cara Mengatasi error 0x80070005 pada Windows Update


1. Download SubInACL tools, dan menginstalnya ke path secara default yang ditawarkan oleh installer saat menginstallnya. Path standar akan menjadi salah satu berikut ini, tergantung pada versi Windows Anda :

untuk Windows 32 bit
%ProgramFiles%\Windows Resource Kits\Tools

untuk Windows 64 bit
%ProgramFiles(x86)%\Windows Resource Kits\Tools

2. buka Notepad, dan kemudian copy dan paste perintah berikut :

@echo off

setlocal

echo.
echo Determine whether we are on an 32 or 64 bit machine
echo.

if "%PROCESSOR_ARCHITECTURE%"=="x86" if "%PROCESSOR_ARCHITEW6432%"=="" goto x86

set ProgramFilesPath=%ProgramFiles(x86)%

goto startResetting

:x86

set ProgramFilesPath=%ProgramFiles%

:startResetting

echo.

if exist "%ProgramFilesPath%\Windows Resource Kits\Tools\subinacl.exe" goto filesExist

echo ***ERROR*** - Could not find file %ProgramFilesPath%\Windows Resource Kits\Tools\subinacl.exe. Double-check that SubInAcl is correctly installed and re-run this script.
goto END

:filesExist

pushd "%ProgramFilesPath%\Windows Resource Kits\Tools"

subinacl.exe /subkeyreg HKEY_LOCAL_MACHINE /grant=administrators=f  /grant=system=f
subinacl.exe /subkeyreg HKEY_CURRENT_USER /grant=administrators=f  /grant=system=f
subinacl.exe /subkeyreg HKEY_CLASSES_ROOT /grant=administrators=f  /grant=system=f
subinacl.exe /subdirectories %windir% /grant=administrators=f /grant=system=f

echo FINISHED.
echo.
echo Press any key to exit . . .
pause >NUL

popd

:END

endlocal

3. Simpan file dengan nama dan ektensi "Reset.cmd".

4. Klik kanan file Reset.cmd di File Explorer (untuk Windows 8.1 dan Windows 8) atau Windows Explorer (untuk  Windows 7 dan Windows Vista), dan kemudian klik Jalankan sebagai administrator. Pada Windows XP, klik dua kali file di Windows Explorer.

5. Tunggu sampai selesai eksekusi, dan kemudian mencoba untuk menginstal pembaruan lagi.

demikian sedikit tutorian tentang cara mengatasi error 0x80070005 di Windows Update, semoga dapat membantu, terimakasih.

Tags :

Related : Mengatasi error 0x80070005 di Windows Update